Colour by code in Excel with VBA - Part 2

Function GetCellColour(Rng As Range, Optional formatType As Integer = 0) As Variant
    Dim colorVal As Variant
    colorVal = Cells(Rng.Row, Rng.Column).Interior.Color
    
    ':: Return error if more than one cell selected.
    If Rng.Cells.Count = 1 Then
    
    
    Select Case formatType
        Case 1  ' ::: WEB HEX :::
            GetCellColour = ZeroPad(Hex((colorVal Mod 256)), 2) & ZeroPad(Hex(((colorVal \ 256) Mod 256)), 2) & ZeroPad(Hex((colorVal \ 65536)), 2)
        Case 2  ' ::: RGB :::
            GetCellColour = (colorVal Mod 256) & ", " & ((colorVal \ 256) Mod 256) & ", " & (colorVal \ 65536)
        Case 3  ' ::: EXCEL COLOUR INDEX :::
            GetCellColour = Cells(Rng.Row, Rng.Column).Interior.ColorIndex
        Case 4  ' ::: VBA USERFORM HEX :::
            GetCellColour = "&H00" & ZeroPad(Hex((colorVal \ 65536)), 2) & ZeroPad(Hex(((colorVal \ 256) Mod 256)), 2) & ZeroPad(Hex((colorVal Mod 256)), 2) & "&"
        
        ' :: COLOUR COMPONENTS ::
        Case 5  ' ::: RED RGB INT 0-255 :::
            GetCellColour = colorVal Mod 256
        Case 6  ' ::: GRN RGB INT 0-255 :::
            GetCellColour = ((colorVal \ 256) Mod 256)
        Case 7  ' ::: BLU RGB INT 0-255 :::
            GetCellColour = (colorVal \ 65536)
        
        Case Else
            GetCellColour = colorVal
    End Select
    
    Else
    ':: Return error if multiple cells picked!
        GetCellColour = "Select one cell!"
    
    End If
    
End Function



Function ZeroPad(Text As String, Cnt As Integer) As String
' :: Text is the string to pad  ::
' :: Cnt is the length to pad to, for example  ZeroPad(12,3) would return a string '012' , Zeropad(12,8) would return '00000012' etc..  ::

Dim StrLen As Integer, StrtString As String, Padded As String, LP As Integer

StrLen = Len(Trim(Text))  '::  CLEAR WHITESPACE IF LEADING SPACES/TABS  ETC.


':: CONDITIONALLY PREFIX ZEROS IF LENGTH OF STRING IS LESS THAN LENGTH OF OUTPUT STRING SPECIFIED
    If StrLen < Cnt Then
    
        For LP = 1 To Cnt - StrLen
        
            Padded = Padded & "0"
        
        Next LP
    
    End If

ZeroPad = Padded & Trim(Text)


End Function